Макрос 1.
Макрос для создания своего стиля ячеек.
Автор: Damian Matacz.
Данный макрос позволяет быстро создавать свои стили ячеек.

Сначала напишите и отформатируйте ячеек, как вам нужно. Например, так как на рисунке ниже.
Рисунок № 1. Создаем свои стили ячеек в новой книге
Создаем новый макрос. Нажимаем alt+F8 или иконку "макрос" на вкладке "Разработчик"
Рисунок № 2. Создаем макрос
Копируем текст макроса ниже.
Sub customStyleAdd()

'Add custom styles to your workbook by setting up cell styles.
'Also calls customStyleDelete if the user wants to delete all
'preexisting custom cell styles.

    Dim cellStyles As Range
    Dim rngCell As Range
    Dim strMsg As String
    Dim answer As Variant

    strMsg = "The following cell styles have been created:" & vbCrLf

'Delete pre-existing custom cell styles

    answer = MsgBox _
        (Prompt:="Do you wish to delete existing custom cell styles?", _
         Buttons:=vbYesNo + vbQuestion, _
         Title:="Delete Existing Cell Styles?")

        If answer = vbYes Then
            Call customStyleDelete
        End If

    On Error Resume Next

'Select range (or use preselected range) as the source of the
'preformatted cell styles

    Set cellStyles = Application.InputBox _
        (Prompt:="Select the custom cell styles you wish to create.", _
        Title:="Cell Style Range", _
        Default:=Selection.Address, _
        Type:=8)

        If IsNull(cellStyles.FormulaArray) = False Then
        On Error GoTo 0
            MsgBox "Please ensure your selection contains:" _
            & vbCrLf & vbCrLf & _
            "- More than one cell" _
            & vbCrLf & vbCrLf & _
            "- Includes preformatted cell styles with labels"
            Exit Sub
        End If

        If cellStyles Is Nothing Then
            On Error GoTo 0
            MsgBox "No range selected."
            Exit Sub
        End If

    For Each rngCell In cellStyles

        If rngCell.Value = "" Then
            GoTo nextcell
        Else
            ActiveWorkbook.Styles.Add Name:=rngCell.Value, _
            BasedOn:=rngCell
            strMsg = strMsg + vbCrLf + vbCrLf + Chr(149) + _
            " " + rngCell.Value
        End If

nextcell:

    Next

    MsgBox strMsg

End Sub

Sub customStyleDelete()

'Deletes all preexisting custom cell styles.

Dim xStyle As Style

    For Each xStyle In ActiveWorkbook.Styles
        If xStyle.BuiltIn = False Then
            xStyle.Delete
        End If
    Next

End Sub
Вставляем текст макрос в новое открывшееся окно VBA.
Для возврата обратно Нажимаем alt+F11.
Рисунок № 3. Копируем - вставляем текст макроса. Создаем макрос
Запускаем макрос созданный макрос. Нажимаем alt+F8. Выбираем макрос "customStyleAdd". Нажимаем выполнить. Далее выбираем "нет". Вводим нужный нам диапазон ячеек. Нажимаем "ок" и новые стили созданы (см. рисунок ниже)
Рисунок № 4. Запускаем макрос "customStyleAdd"
Made on
Tilda